/*REPLICATION FILE

Nyhan, Brendan. 2010. Why the "Death Panel" Myth Wouldn't Die: Misinformation in the Health Care Reform Debate. The Forum 8(1).

Note: This .do file requires data from the Roper Center for Public Opinion Research. Subscribers can download datasets and codebooks for the two surveys described below via RoperExpress. See the codebooks for details on the surveys used, coding of the data, and question wording.
*/

clear
set more off

/*
September 1993 CBS-NYT poll from Roper:

From what you have heard, do you think that if the (President Bill) Clinton health care plan is adopted, you would be able to keep seeing that doctor (your own doctor), or wouldn't it be possible?

57%  Able to keep with doctor
23   Not possible
20   Don't know/No answer

Methodology: Conducted by CBS News/New York Times, September 16-September 19, 1993 and based on telephone interviews with a national adult sample of 1,136. [USCBSNYT.092193.R49]

As of now, do you think you have a good understanding of what the (President Bill) Clinton health care plan will mean, or is it too early to know that yet?

13% Good understanding
84% Too early
3% Don't know/No answer

Methodology: Conducted by CBS News/New York Times, September 16 - September 19, 1993 and based on 1,136 telephone interviews. Sample: national adult. [USCBSNYT.092193.R65]
*/

clear
infix 3 lines 1: gender 22 hcbetter 47 2: nomdchoice 17 hcknow2a 35 party1 67 party2 68 3: weight 49-54 censusregion 55 education 71 agegroup 74 race 75 using "Sep93a.dat"

replace weight=weight/1000

svyset [pweight=weight]

/*replicate published findings*/
svy: tab nomdchoice
svy: tab hcknow2a

/*with leaners*/
gen gop=0
replace gop=1 if party1==1 | party2==1

gen dem=0
replace dem=1 if party1==2 | party2==2

gen ind=(gop==0 & dem==0)

svy: tab nomdchoice,subpop(gop)
svy: tab hcknow2a,subpop(gop)

/*recoding and variable construction*/

gen male=0
replace male=1 if gender==1
gen black=0
replace black=1 if race==2
gen south=0
replace south=1 if censusregion==3

gen college=0
replace college=1 if education==4

recode nomdchoice (9=1) (1=0)
recode hcknow2a (2=0) (9=0)
recode agegroup (9=.)

gen gopXhcknow2a=gop*hcknow2a
gen indXhcknow2a=ind*hcknow2a

tab agegroup,gen(ag)

gen nomdchoice2=.
replace nomdchoice2=0 if nomdchoice==0 | nomdchoice==1
replace nomdchoice2=1 if nomdchoice==2

svy: tab nomdchoice2
svy: tab nomdchoice2,subpop(gop)

svy: tab hcbetter
svy: tab hcbetter,subpop(gop)

gen nongop=(gop==0)
svy: tab nomdchoice2 hcbetter,row
svy: tab nomdchoice2 hcbetter,subpop(gop) row
svy: tab nomdchoice2 hcbetter,subpop(nongop) row

gen gopnoknow=gop*(hcknow2a==0)
svy: tab nomdchoice2 hcbetter,subpop(gopnoknow) row
svy: tab nomdchoice2 hcbetter,subpop(gopXhcknow2a) row

/*logit models for predicted prob. graph*/
svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
nlcom _b[gop]-_b[ind]
nlcom _b[hcknow2a]+_b[gopXhcknow2a]
nlcom _b[hcknow2a]+_b[indXhcknow2a]
nlcom _b[gopXhcknow2a]-_b[indXhcknow2a]
est store cl93

margins,at(gop=0 ind=0 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o1)
matrix drop A

svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=0 hcknow2a=1 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o2)
matrix drop A

svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=1 ind=0 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o3)
matrix drop A

svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=1 ind=0 hcknow2a=1 gopXhcknow2a=1 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o4)
matrix drop A

svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=1 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o5)
matrix drop A

svy: logit nomdchoice2 gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=1 hcknow2a=1 gopXhcknow2a=0 indXhcknow2a=1 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o6)
matrix drop A

keep o1-o6
xpose,clear
keep v1
replace v1=v1*100
gen gop=0
replace gop=1 if _n==3 | _n==4
gen ind=0
replace ind=1 if _n==5 | _n==6
gen know=0
replace know=1 if _n==2 | _n==4 | _n==6

twoway (connected v1 know if gop==0 & ind==0,color(blue) lpattern (shortdash_dot)) (connected v1 know if ind==1,color(green) msymbol(diamond) lpattern(dash)) (connected v1 know if gop==1,xscale(range (-.2 1.2)) color(red) msymbol(square) lpattern(solid)), xscale(titlegap(*8))  graphregion(fcolor(white) ifcolor(none)) plotregion(fcolor(none) lcolor(white) ifcolor(none) ilcolor(none)) legend(label(1 "Democrats") label(2 "Independents") label (3 "Republicans") rows(1) size(*.8) symxsize(*.8) symysize(*.8)) ytitle("",size(*1)) ylabel(0 "0%" 20 "20%" 40 "40%" 60 "60%" 80 "80%",grid gmax labsize(*1) angle(horizontal)) xtitle("") xlabel(0 "    Too early/don't know" 1 "Good understanding   ",labsize(small)) xtitle("Perceived knowledge of Clinton plan",size(*1.1)) name(cl93,replace) title("Lose your doctor (1993)",size(*1))

/*
2009 CNN/ORC poll from Roper:

Based on what you have read or heard about (Barack) Obama's health care plan, please tell me whether you think each of the following would or would not happen if that plan became law....If Obama's plan became law, do you think senior citizens or seriously-ill patients would die because government panels would prevent them from getting the medical treatment they needed?
CNN/Opinion Research Corporation Poll, Sep, 2009

41% Would happen
57% Would not happen
2% No opinion

Survey by Cable News Network. Methodology: Interviewing conducted by Opinion Research Corporation, September 11 - September 13, 2009 and based on 1,012 telephone interviews. Sample: national adult. [USORC.091409A.R14]

As you may know, President (Barack) Obama presented his health care reform proposals to Congress and the American people in a broadcast address last Wednesday evening (September 9, 2009). How much do you know about the details of President Obama's health care proposals--a great deal, a good amount, only some, or not much at all?
CNN/Opinion Research Corporation Poll, Sep, 2009

11% Great deal
32% Good amount
37% Only some
20% Not much at all
 
Survey by Cable News Network. Methodology: Interviewing conducted by Opinion Research Corporation, September 11 - September 13, 2009 and based on 1,012 telephone interviews. Sample: national adult. [USORC.091409A.R18]
*/

clear
infix hcsupport 26 gender 46 deathpanel 34 illegalhc 36 hcknow2a 38 party1 60 party2 61 weight 63-69 censusregion 3 education 47 agegroup 50-51 race1 53 race2 54 race3 55 race4 56 using "c200914.dat"

replace weight=weight/1000

gen male=0
replace male=1 if gender==1
gen black=0
replace black=1 if race1==2 
gen south=0
replace south=1 if censusregion==3

/*with leaners*/
gen gop=0
replace gop=1 if party1==1 | party2==2

gen dem=0
replace dem=1 if party1==2 | party2==1

gen ind=(gop==0 & dem==0)

gen college=0
replace college=1 if education==6 | education==7

recode hcknow2a (4=0) (9=0) (2=1) (3=0)
recode agegroup (99=.)

svyset [pweight=weight]

/*replicate published finding*/
svy: tab deathpanel
svy: tab deathpanel,subpop(gop)

/*collapsing don't know since so few*/
recode hcsupport (2=0) (9=0)
recode deathpanel (2=0) (9=0)
recode illegalhc (2=0) (9=0)

gen gopXhcknow2a=gop*hcknow2a
gen indXhcknow2a=ind*hcknow2a

gen nongop=(gop==0)
svy: tab deathpanel hcsupport, row
svy: tab deathpanel hcsupport,subpop(gop) row
svy: tab deathpanel hcsupport,subpop(nongop) row

gen agegroup2=agegroup
recode agegroup2 (2=1) (3=1) (4=2) (5=2) (6=2) (7=3) (8=3) (9=3) (10=3) (11=4) (12=4) (13=4)
tab agegroup2, gen(ag)

svy: logit illegalhc gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
nlcom _b[gop]-_b[ind]
nlcom _b[hcknow2a]+_b[gopXhcknow2a]
nlcom _b[hcknow2a]+_b[indXhcknow2a]
nlcom _b[gopXhcknow2a] - _b[indXhcknow2a]

/*logit models for predicted prob. graph*/
svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
nlcom _b[gop]-_b[ind]
nlcom _b[hcknow2a]+_b[gopXhcknow2a]
nlcom _b[hcknow2a]+_b[indXhcknow2a]
nlcom _b[gopXhcknow2a] - _b[indXhcknow2a]
est store ob09

margins,at(gop=0 ind=0 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o1)
matrix drop A

svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=0 hcknow2a=1 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o2)
matrix drop A

svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=1 ind=0 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o3)
matrix drop A

svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=1 ind=0 hcknow2a=1 gopXhcknow2a=1 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o4)
matrix drop A

svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=1 hcknow2a=0 gopXhcknow2a=0 indXhcknow2a=0 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o5)
matrix drop A

svy: logit deathpanel gop ind hcknow2a gopXhcknow2a indXhcknow2a college male black ag2-ag4
margins,at(gop=0 ind=1 hcknow2a=1 gopXhcknow2a=0 indXhcknow2a=1 college=0 male=0 black=0 ag2=0 ag3=1 ag4=0) vce(unconditional) post
matrix A=e(b)
svmat A,names(o6)
matrix drop A

keep o1-o6
xpose,clear
keep v1
replace v1=v1*100
gen gop=0
replace gop=1 if _n==3 | _n==4
gen ind=0
replace ind=1 if _n==5 | _n==6
gen know=0
replace know=1 if _n==2 | _n==4 | _n==6

twoway (connected v1 know if gop==0 & ind==0,color(blue) lpattern (shortdash_dot)) (connected v1 know if ind==1,color(green) msymbol(diamond) lpattern(dash)) (connected v1 know if gop==1,xscale(range (-.2 1.2)) color(red) msymbol(square) lpattern(solid)),scheme(s1mono) xscale(titlegap(*8))  graphregion(fcolor(white) ifcolor(none)) plotregion(fcolor(none) lcolor(white) ifcolor(none) ilcolor(none)) legend(label(1 "Democrats") label(2 "Independents") label (3 "Republicans") rows(1) size(*.8) symxsize(*.8) symysize(*.8)) ytitle("",size(*1)) ylabel(0 "0%" 20 "20%" 40 "40%" 60 "60%" 80 "80%",grid gmax labsize(*1) angle(horizontal)) xtitle("") xlabel(0 "Some/not much" 1 "Good/great",labsize(small)) xtitle("Perceived knowledge of Obama plan",size(*1.1)) name(ob09,replace) title("Death panels (2009)",size(*1)) 

grc1leg cl93 ob09, ycommon legendfrom(ob09) 
graph export "hc-misp.eps", as(eps) replace


estout cl93 ob09, replace varwidth(25) collabels("") cells(b(star fmt(%9.2f)) se(par fmt(%9.2f))) stats(ll N, fmt(%9.2f %9.0f) labels("Log-likelihood" "N")) starlevels(* 0.10 ** 0.05 *** 0.01)